Technical blog

September 11, 2009

Flex: mxml vs ActionScript

Filed under: flex — Tags: , — paawak @ 01:40

This might look rather silly, but still had to give in to temptation :). Since I had worked on Swings as well, had to see if I could code a create a popup window with ActionScript. Well, of course you can, but I am rather new to Flex and most of the tutorial, for some unknown reason, choose not to mention this topic. So I decided to give it a shot.

Below is a popup window coded in mxml. Its called ItemSelectDialog.mxml.

<?xml version="1.0" encoding="utf-8"?>
<mx:TitleWindow xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"  
    showCloseButton="true" close="close();">
 
    <mx:Script>
        <![CDATA[
            import mx.managers.PopUpManager;
 
            private function close():void {
                // Put any clean-up code here.
                PopUpManager.removePopUp(this);
            }
 
        ]]>
    </mx:Script>
 
 
	<mx:Label x="39" y="77" text="ItemName:"/>
	<mx:Label x="0" y="10" text="Item Search" width="400" textAlign="center" fontSize="18" fontWeight="bold"/>
	<mx:ComboBox x="140" y="75" id="itemNames">
	    <mx:ArrayCollection id="itemArray">
	    <mx:Object data="0" label="Item-0"/>
	    <mx:Object data="1" label="Item-1"/>
	    <mx:Object data="2" label="Item-2"/>
	    </mx:ArrayCollection>
	</mx:ComboBox>
	<mx:Button x="103" y="214" label="Cancel" id="cancel" click="close();"/>
	<mx:Button x="230" y="214" label="Add" id="add" click="close();"/>
 
</mx:TitleWindow>

This is how you invoke it from another mxml:

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" >
 
    <mx:Script>
        <![CDATA[
            import mx.managers.PopUpManager;
            import mx.core.IFlexDisplayObject;
 
            private function showAddItemDialog():void {
                // Create a modal TitleWindow container.
                var itemWindow:IFlexDisplayObject = PopUpManager.createPopUp(this, ItemSelectDialog, true);
            }
 
        ]]>
    </mx:Script>
 
	<mx:Button x="556" y="249" label="Add Item" id="addItem" click="showAddItemDialog();"/>
 
</mx:Application>

And this is how its ActionScript counterpart looks like. Its called ItemSelectionDialog.as.

package com.swayam.flex.exp {
 
    import  mx.containers.TitleWindow;
    import  mx.controls.Label;
    import  mx.controls.ComboBox;
    import  mx.controls.Button;
    import mx.managers.PopUpManager;
    import mx.events.CloseEvent;
    import flash.events.IEventDispatcher;
    import flash.events.MouseEvent;
 
    public class ItemSelectionDialog extends TitleWindow {
 
        [Bindable]
        private var itemsArray:Array = new Array();
 
        private var cbItemList:ComboBox;
 
        public function ItemSelectionDialog() {
 
            initComponents();
 
            showCloseButton=true;
 
            layout="absolute";
 
            width = 500;
            height = 300;
 
            addEventListener(CloseEvent.CLOSE, closeWindow);
 
        }
 
        private function initComponents():void {
 
            var lbTitle:Label = new Label();
            lbTitle.text = "Item Search";
            lbTitle.x = 0;
            lbTitle.y = 10;
            /*lbTitle.textAlign="center";
            lbTitle.fontSize=18;
            lbTitle.fontWeight="bold";*/
            addChild(lbTitle);
 
            var lbItemName:Label = new Label();
            lbItemName.text = "ItemName:";
            lbItemName.x = 39;
            lbItemName.y = 75;
            addChild(lbItemName);
 
            //put some elements in the combo
            var count:int = 0;
 
            for (; count < 10; count++) {
                var content:Object = new Object();
                content["label"] = "Item-" + count;
                content["data"] = count;
                itemsArray[count] = content;
            } 
 
            cbItemList = new ComboBox();
            cbItemList.x = 140;
            cbItemList.y = 75;
            cbItemList.dataProvider = itemsArray;
            addChild(cbItemList);
 
            var btCancel:Button = new Button();
            btCancel.label = "Cancel";
            btCancel.x = 103;
            btCancel.y = 214;
            btCancel.addEventListener(MouseEvent.CLICK, closeOnClick);
            addChild(btCancel);
 
            var btAdd:Button = new Button();
            btAdd.label = "Add";
            btAdd.x = 230;
            btAdd.y = 214;
            btAdd.addEventListener(MouseEvent.CLICK, addAndClose);
            addChild(btAdd);
 
        }
 
        private function closeWindow(event:CloseEvent):void {
            close();
        }
 
        private function closeOnClick(event:MouseEvent):void {
            close();
        }
 
        private function addAndClose(event:MouseEvent):void {
 
        	if (cbItemList.selectedItem != null) {
                close();
        	}
 
        }
 
        private function close():void {
            PopUpManager.removePopUp(this);
        }
 
    }
 
}

You can use it just like its mxml counterpart, just make sure that you import the class.

...
            private function showAddItemDialog():void {
                // Create a modal TitleWindow container.
                var itemWindow:IFlexDisplayObject = PopUpManager.createPopUp(this, ItemSelectionDialog, true);
            }
...

This is how it looks like:
popup-actionscript

September 10, 2009

Accessing Java objects with Flex remoting

Filed under: flex, java — Tags: , , , — paawak @ 20:23

This post talks about how we:

  1. Query the database through Flex by invoking a server side Java object (the ItemDao) by Flex remoting with Blaze DS.
  2. Displays the result, which is a java.util.List<Item> in a DataGrid and a ComboBox.

Now that we have successfully configured Spring with Flex, we would like to access server side Java objects, which we expose through Spring.

We will query Items from the database using Spring/Hibernate through the ItemDao.

This is how my Item.java looks like:

 
/**
 * 
 * @author paawak
 */
@Entity
public class Item implements Serializable {
 
    private static final long serialVersionUID = 340952899861L;
 
    @Id
    @GeneratedValue(strategy = GenerationType.AUTO)
    private Long id;
 
    @Column(length = 20, unique = true)
    private String code;
 
    @Column(length = 15, unique = true)
    private String name;
 
    @Column(length = 50)
    private String description;
 
    public Long getId() {
        return id;
    }
 
    public void setId(Long id) {
        this.id = id;
    }
 
    public String getCode() {
        return code;
    }
 
    public void setCode(String code) {
        this.code = code;
    }
 
    public String getName() {
        return name;
    }
 
    public void setName(String name) {
        this.name = name;
    }
 
    public String getDescription() {
        return description;
    }
 
    public void setDescription(String description) {
        this.description = description;
    }
 
}

And this is how my ItemDao.java looks like:

/**
 * 
 * @author paawak
 */
public class ItemDao extends HibernateDaoSupport {
 
    @SuppressWarnings("unchecked")
    public List<Item> getAll() {
        return super.getHibernateTemplate().loadAll(Item.class);
    }
 
}

As is obvious, I configure the ItemDao through Spring and then expose it as below:

 
...
<flex:remoting-destination ref="itemDao"/>
...

The one thing to remember here is that, Flex handles remote access through call back mechanism. That is, the call to the Java object, is asynchronous. The call returns immediately. However, the result (or the error) is got asynchronously by registering suitable listeners.

The following code snippet illustrates this:

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
    initialize="initData();">
 
    <mx:Script>
        <![CDATA[           
            import mx.controls.Alert;
            import mx.rpc.remoting.RemoteObject;
            import mx.rpc.events.ResultEvent;
            import mx.rpc.events.FaultEvent;
            import mx.collections.ArrayCollection;
 
            [Bindable]
            private var itemsMultiArray:ArrayCollection;
 
            private function initData():void {
 
                //call the getAll() method on the itemDao remote object, which has been exposed
                var itemRO:RemoteObject = new RemoteObject();
                itemRO.destination = "itemDao";
                itemRO.addEventListener(ResultEvent.RESULT, getItemListResultHandler);
                itemRO.addEventListener(FaultEvent.FAULT, faultHandler);
                itemRO.getOperation("getAll").send();
 
            }
 
            private function getItemListResultHandler(event:ResultEvent):void {
 
                itemsMultiArray = (ArrayCollection)(event.result);
 
            }
 
 
            private function faultHandler (event:FaultEvent):void {
             // Deal with event.fault.faultString, etc.
                Alert.show(event.fault.faultString, 'Error');
            }
 
        ]]>
    </mx:Script>
 
	<mx:DataGrid id="itemDetails" width="511" dataProvider="{itemsMultiArray}">
		<mx:columns>
			<mx:DataGridColumn headerText="ID" dataField="id"/>
			<mx:DataGridColumn headerText="Name" dataField="name"/>
			<mx:DataGridColumn headerText="Code" dataField="code"/>
		</mx:columns>
	</mx:DataGrid>
 
 
</mx:Application>

This is how it looks like:
flex_remote_object-1

The most important thing to note here is that the result that is got back in the call back function, should be cast with the proper data type in Flex. This is the link which has the details under the head Converting data from Java to ActionScript. From here we get to know the correct casting. In this case, we are casting the result into mx.collections.ArrayCollection since it is of java.util.List type.

Also note that though each element in the array is of the type Item, it can be accessed by its bean attribute name. That is how we can access the id, name and code in the DataGrid. Note that you cannot invoke the getter method like getId() on the object, it will not work.

So far, we have used a DataGrid which can extract data based on the attribute names. What if we use a ComboBox which needs a two dimensional array with data and label attributes? This is the code snippet of the modified getItemListResultHandler():

...
           [Bindable]
            private var itemComboArray:Array = new Array();
...
            private function getItemListResultHandler(event:ResultEvent):void {
 
                itemsMultiArray = (ArrayCollection)(event.result);
 
                var count:int = 0;
 
                for each (var item:Object in itemsMultiArray) {
                    var content:Object = new Object();
                    content["label"] = item.name;
                    content["data"] = item.id;
                    itemComboArray[count++] = content;
                } 
 
            }

And this is the code to add the ComboBox:

...
<mx:ComboBox id="itemCombo"  dataProvider="{itemComboArray}"></mx:ComboBox>
...

The screen looks like this now:
flex_remote_object-2

Powered by WordPress